( MakeFishies.MUF              a toy               by Ginger@FurToonia )
(                                                                      )
( Makes a fishtank full of randomly moving fish.                       )
(
  Props:   < on trigger>
  @set <trigger> = _fish/fish1: <desc of fish; 8 chars or less>
                 = _fish/fish2:
                 = _fish/fish3:
                 = _fish/fish4:
                 = _fish/fish5:
                 = _fish/fish6: <you may want to turn some backwards>
                 = _fish/depth: <# lines deep tank will be>
                 = _fish/bubbles: <'on' for bubbles, 'off' for none>
  If there are no _fish/fish# props set, the tank will be empty.
)
lvar depth
$define addfish (adds random fish to line)
    trig "_fish/fish" random 6 % 1 + intostr strcat
    getpropstr 8 strcut pop strcat
$enddef
$define addbubble (adds bubble if bubbles=on)
    trig "_fish/bubbles" getpropstr dup "on" stringcmp
    0 = swap "" stringcmp 0 = or if "                    "
    random 20 % 1 + strcut pop "." strcat strcat then
$enddef
$define addspaces (adds random # of spaces between 1 and 15)
"               "
  random 15 % 1 + strcut pop strcat
$enddef
$define endline (ends a tank line)
 "                                                            "
 strcat 61 strcut pop "|" strcat say
$enddef
$define say me @ swap notify $enddef
: draw_line
addspaces addbubble addspaces addfish addbubble addspaces endline
;
: draw_plant
random 30 % 1 + dup 10 < if pop
  "|      )" draw_line "|   ) (" draw_line "|  (  )" draw_line
  "| ) ) (" draw_line  "| ( (  )" draw_line
exit then 20 < if
  "|      (" draw_line "|   (   )" draw_line "|    ) (" draw_line
  "| ( (   )" draw_line "|  ) ) (" draw_line
exit then
  "|      )" draw_line "|  (  (" draw_line "|   ) )" draw_line
  "| ) ((" draw_line "|(  ) )" draw_line 
;
: main
  trig "_fish/depth" getpropstr dup number? not if pop 12
  else atoi then 6 - depth !
(123456789 123456789 123456789 123456789 123456789 123456789 12) (62)
"|------------------------------------------------------------|" say
"|^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^|" say
  begin depth @ 0 = not while
  "|" draw_line depth @ 1 - depth ! repeat
  draw_plant
"|%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%|" say
;