( ExitsClone.MUF                                     by Ginger@FurToonia )
(                                                                        )
( Standard 'exits' clone, modified so the screen width is a little wider )
( but otherwise intact. My code; only the format was copied [from Bunny] )
( Type 'exits #help' for help.                                           )
lvar object
lvar mexit
lvar entry
lvar link
: help
"Exits Clone                                   by Ginger@FurToonia" .tell
"    " .tell
"Syntax:" .tell
"      exits #help      --    this screen" .tell
"            here       --    list exits on this room" .tell
"            me         --    list exits on yourself" .tell
"            <object>   --    list exits on <object>" .tell
"            db#        --    list exits on db#" .tell
"   " .tell
"You can only list exits on objects you own.  Wizards can list exits" .tell
"on anything." .tell
;
: get_exits
  object @ exits dup 1 2 - dbref dbcmp if
  me @ "No exits attached." notify exit then
  begin dup 1 2 - dbref dbcmp not while
  dup mexit !
  name "                          " strcat 26 strcut pop
  "(#" mexit @ intostr
  "      " strcat 6 strcut pop strcat ") Dest: " strcat strcat
  mexit @ getlink link !
  link @ 1 2 - dbref dbcmp if "         >>>NOTHING<<<"
  strcat me @ swap notify mexit @ next continue then
  link @ 1 4 - dbref dbcmp if "          >>>HOME<<<"
  strcat me @ swap notify mexit @ next continue then
  link @ name
  "                          " strcat 26 strcut pop
  "(#" link @ intostr
  "      " strcat 6 strcut pop strcat ")" strcat strcat strcat
  me @ swap notify
  mexit @ next repeat
 exit
;
: me_own?
  me @ "Wizard" flag? if get_exits exit then
  object @ owner me @ dbcmp if get_exits exit then
  me @ "You don't control that." notify
 exit
;
: match_entry
  entry @ match dup 1 2 - dbref dbcmp if
          me @ "I don't see that here." notify exit then
          dup 1 3 - dbref dbcmp if
          me @ "I don't know which one you mean!" notify exit then
          dup 1 4 - dbref dbcmp if
          me @ "That's a silly name for an object!" notify exit then
          dup program? if
          me @ "Programs don't have exits attached." notify exit then
          dup exit? if
          me @ "Exits can't have exits attached." notify exit then
          entry @ match object ! me_own? exit
;
: collate_entry
  entry @ "" stringcmp 0 = if loc @ object ! me_own? exit then
  entry @ "here" stringcmp 0 = if loc @ object ! me_own? exit then
  entry @ "me" stringcmp 0 = if me @ object ! me_own? exit then
  entry @ dup "*" stringpfx if 1 strcut swap pop
          .pmatch object ! me_own? exit then
  entry @ dup "#" stringpfx if 1 strcut swap pop then
          dup number? if else match_entry exit then
          atoi dbref
          dup program? if me @ "Programs don't have exits attached."
  notify exit then
          dup exit? if me @ "Exits can't have exits attached."
  notify exit then
          dup ok? if object ! me_own? exit then
 exit
;
: main
  dup "#help" stringcmp 0 = if pop help exit then
  entry !
  collate_entry
  me @ "Done." notify
  exit
;